@echo off

if [%1] neq [] (set VERSION=%1) else (set /p VERSION=Version? )
if %VERSION%==trunk (
    set LOC=trunk
    rem Remove previous trunk builds
    del /Q htmlpurifier-trunk*
) else (set LOC=tags/%VERSION%)
set NAME=htmlpurifier-%VERSION%

svn export --force http://htmlpurifier.org/svnroot/htmlpurifier/%LOC% %NAME%

rem Regular zip
zip -r %NAME%.zip %NAME%

rem Lite zip
set SNAME=%NAME%-lite
mkdir %SNAME%
xcopy %NAME%\library %SNAME%\library\ /E /Q
call copy-meta-files %NAME% %SNAME%
zip -r %SNAME%.zip %SNAME%
rmdir /S /Q %SNAME%

rem Standalone zip
set SNAME=%NAME%-standalone
mkdir %SNAME%
call php %NAME%\maintenance\merge-library.php
xcopy %NAME%\library\standalone %SNAME%\standalone\ /E /Q
copy %NAME%\library\HTMLPurifier.standalone.php %SNAME%\HTMLPurifier.standalone.php
call copy-meta-files %NAME% %SNAME%
zip -r %SNAME%.zip %SNAME%
rmdir /S /Q %SNAME%
rmdir /S /Q %NAME%\library\standalone
rmdir /S /Q %NAME%\tests\blanks
mkdir %NAME%\tests\blanks
del %NAME%\library\HTMLPurifier.standalone.php

rmdir /S /Q %NAME%